PakFu/meson.build at main · themuffinator/PakFu · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
project(
  'pakfu',
  'cpp',
  version: run_command(
    'python',
    '-c',
    'from pathlib import Path; print(Path("VERSION").read_text().strip())',
    check: true
  ).stdout().strip(),
  default_options: [
    'cpp_std=c++20',
    'warning_level=2',
    'werror=false',
  ],
)

qt6_modules = ['Core', 'Gui', 'Widgets', 'OpenGL', 'OpenGLWidgets', 'Network', 'Multimedia', 'MultimediaWidgets']
qt6_core_modules = ['Core', 'Gui']
qt6 = import('qt6')
qt6_dep = dependency('qt6', modules: qt6_modules, method: 'config-tool', required: false)
if not qt6_dep.found()
  qt6_dep = dependency('qt6', modules: qt6_modules, method: 'pkg-config', required: false)
endif
if not qt6_dep.found()
  error('Qt 6 not found. Install Qt 6 and ensure qmake6 is on PATH or pkg-config is available.')
endif
qt6_core_dep = dependency('qt6', modules: qt6_core_modules, method: 'config-tool', required: false)
if not qt6_core_dep.found()
  qt6_core_dep = dependency('qt6', modules: qt6_core_modules, method: 'pkg-config', required: false)
endif
if not qt6_core_dep.found()
  error('Qt 6 Core/Gui modules not found. Install Qt 6 and ensure qmake6 is on PATH or pkg-config is available.')
endif

subdir('src')

python_for_tests = find_program('python', 'python3', required: false)
if python_for_tests.found()
  test(
    'shell-integration-metadata',
    python_for_tests,
    args: [files('scripts/validate_shell_integration.py')],
  )
endif